mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-02-16 09:14:18 +00:00
1b9dbca826
This incorporates: 2019-11-24 Fix errors in C++ mode on mingw 2019-11-24 time_r: Fix for mingw (regression from 2019-11-16) 2019-11-24 sys_time: Fix errors in C++ mode on mingw 2019-11-22 intprops: INT_MULTIPLY_WRAPV speedup for GCC 8.4+ 2019-11-21 Disable many _GL_CXXALIASWARN on non-glibc 2019-11-21 Fix various errors in _GL_CXXALIAS_SYS invocations 2019-11-19 intprops: INT_MULTIPLY_WRAPV speedup for GCC 9.3+ 2019-11-18 stdint: Define [u]intptr_t correctly on 64-bit native Windows 2019-11-18 stdint: Fix value of WINT_MAX when we override wint_t 2019-11-18 stdint: Avoid "conflicting types" error on mingw 5.22 2019-11-16 time_r: Fix for mingw 2019-11-06 regex: now back in sync with glibc * lib/intprops.h, lib/regexec.c, lib/signal.in.h: * lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h: * lib/string.in.h, lib/sys_select.in.h, lib/sys_time.in.h: * lib/time.in.h, lib/unistd.in.h, m4/time_r.m4: Copy from Gnulib.
99 lines
3.3 KiB
Text
99 lines
3.3 KiB
Text
dnl Reentrant time functions: localtime_r, gmtime_r.
|
|
|
|
dnl Copyright (C) 2003, 2006-2019 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl Written by Paul Eggert.
|
|
|
|
AC_DEFUN([gl_TIME_R],
|
|
[
|
|
dnl Persuade glibc and Solaris <time.h> to declare localtime_r.
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
|
|
AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
|
|
AC_REQUIRE([AC_C_RESTRICT])
|
|
|
|
dnl Some systems don't declare localtime_r() and gmtime_r() if _REENTRANT is
|
|
dnl not defined.
|
|
AC_CHECK_DECLS([localtime_r], [], [],
|
|
[[/* mingw's <time.h> provides the functions asctime_r, ctime_r,
|
|
gmtime_r, localtime_r only if <unistd.h> or <pthread.h> has
|
|
been included before. */
|
|
#if defined __MINGW32__
|
|
# include <unistd.h>
|
|
#endif
|
|
#include <time.h>
|
|
]])
|
|
if test $ac_cv_have_decl_localtime_r = no; then
|
|
HAVE_DECL_LOCALTIME_R=0
|
|
fi
|
|
|
|
AC_CHECK_FUNCS_ONCE([localtime_r])
|
|
if test $ac_cv_func_localtime_r = yes; then
|
|
HAVE_LOCALTIME_R=1
|
|
AC_CACHE_CHECK([whether localtime_r is compatible with its POSIX signature],
|
|
[gl_cv_time_r_posix],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[/* mingw's <time.h> provides the functions asctime_r, ctime_r,
|
|
gmtime_r, localtime_r only if <unistd.h> or <pthread.h> has
|
|
been included before. */
|
|
#if defined __MINGW32__
|
|
# include <unistd.h>
|
|
#endif
|
|
#include <time.h>
|
|
]],
|
|
[[/* We don't need to append 'restrict's to the argument types,
|
|
even though the POSIX signature has the 'restrict's,
|
|
since C99 says they can't affect type compatibility. */
|
|
struct tm * (*ptr) (time_t const *, struct tm *) = localtime_r;
|
|
if (ptr) return 0;
|
|
/* Check the return type is a pointer.
|
|
On HP-UX 10 it is 'int'. */
|
|
*localtime_r (0, 0);]])
|
|
],
|
|
[gl_cv_time_r_posix=yes],
|
|
[gl_cv_time_r_posix=no])
|
|
])
|
|
if test $gl_cv_time_r_posix = yes; then
|
|
REPLACE_LOCALTIME_R=0
|
|
else
|
|
REPLACE_LOCALTIME_R=1
|
|
fi
|
|
else
|
|
HAVE_LOCALTIME_R=0
|
|
dnl On mingw, localtime_r() is defined as an inline function; use through a
|
|
dnl direct function call works but the use as a function pointer leads to a
|
|
dnl link error.
|
|
AC_CACHE_CHECK([whether localtime_r exists as an inline function],
|
|
[gl_cv_func_localtime_r_inline],
|
|
[AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[/* mingw's <time.h> provides the functions asctime_r, ctime_r,
|
|
gmtime_r, localtime_r only if <unistd.h> or <pthread.h> has
|
|
been included before. */
|
|
#if defined __MINGW32__
|
|
# include <unistd.h>
|
|
#endif
|
|
#include <time.h>
|
|
]],
|
|
[[time_t a;
|
|
struct tm r;
|
|
localtime_r (&a, &r);
|
|
]])
|
|
],
|
|
[gl_cv_func_localtime_r_inline=yes],
|
|
[gl_cv_func_localtime_r_inline=no])
|
|
])
|
|
if test $gl_cv_func_localtime_r_inline = yes; then
|
|
REPLACE_LOCALTIME_R=1
|
|
fi
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/time_r.c.
|
|
AC_DEFUN([gl_PREREQ_TIME_R], [
|
|
:
|
|
])
|