mirror of
git://git.sv.gnu.org/emacs.git
synced 2026-06-14 12:31:25 +00:00
c7bca9f340
* lisp/erc/erc-pcomplete.el (erc-completion-mode): New alias for the variable `erc-pcomplete-mode' to complement the function alias of the corresponding minor-mode command. Given that user code operating on the value of `erc-modules' needs to detect whether members are active, it only makes sense to address this specially. Before this change, applying `bound-and-true-p' to `erc-completion-mode' would always return nil, even when the module was active. For normal aliases, that's indeed expected because `define-erc-module' doesn't automatically define a mode variable for a non-nil ALIAS argument. Although in the long term it probably should, while also obsoleting the "new" alias simultaneously, that would likely break some user code and doubtless complicate things majorly for `pcomplete', the one in-tree outlier. The latter module would then require changing either its preferred name, the one advertised by `erc-modules' in its Custom definition, to `pcomplete' or its primary name to `completion'. Both are quite churn-inducing.
303 lines
10 KiB
EmacsLisp
303 lines
10 KiB
EmacsLisp
;;; erc-pcomplete.el --- Provides programmable completion for ERC -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2002-2004, 2006-2026 Free Software Foundation, Inc.
|
|
|
|
;; Author: Sacha Chua <sacha@free.net.ph>
|
|
;; Maintainer: Amin Bandali <bandali@gnu.org>, F. Jason Park <jp@neverwas.me>
|
|
;; Keywords: comm
|
|
;; URL: https://www.emacswiki.org/emacs/ErcCompletion
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; This file replaces erc-complete.el. It provides nick completion
|
|
;; for ERC based on pcomplete. If you do not have pcomplete, you may
|
|
;; try to use erc-complete.el.
|
|
;;
|
|
;; To use, (require 'erc-auto) or (require 'erc-pcomplete), then
|
|
;; (erc-pcomplete-mode 1)
|
|
;;
|
|
;; If you want nickname completions ordered such that the most recent
|
|
;; speakers are listed first, set
|
|
;; `erc-pcomplete-order-nickname-completions' to t.
|
|
;;
|
|
;; See CREDITS for other contributors.
|
|
;;
|
|
;;; Code:
|
|
|
|
(require 'pcomplete)
|
|
(require 'erc)
|
|
(require 'time-date)
|
|
|
|
(defgroup erc-pcomplete nil
|
|
"Programmable completion for ERC."
|
|
:group 'erc)
|
|
|
|
(defcustom erc-pcomplete-nick-postfix ":"
|
|
"When `pcomplete' is used in the first word after the prompt,
|
|
add this string to nicks completed."
|
|
:type 'string)
|
|
|
|
(defcustom erc-pcomplete-order-nickname-completions t
|
|
"If t, order nickname completions with the most recent speakers first."
|
|
:type 'boolean)
|
|
|
|
;;;###autoload(put 'Completion 'erc--module 'completion)
|
|
;;;###autoload(put 'pcomplete 'erc--module 'completion)
|
|
;;;###autoload(put 'completion 'erc--feature 'erc-pcomplete)
|
|
;;;###autoload(autoload 'erc-completion-mode "erc-pcomplete" nil t)
|
|
(put 'completion 'erc-group 'erc-pcomplete)
|
|
;; For historical reasons, (the downcased version of) this module's
|
|
;; alias is the canonical name used by `erc-modules'. But user code
|
|
;; still needs to detect whether the module is enabled based on that
|
|
;; name alone, hence this variable alias.
|
|
(defvaralias 'erc-completion-mode 'erc-pcomplete-mode)
|
|
(define-erc-module pcomplete Completion
|
|
"In ERC Completion mode, the TAB key does completion whenever possible."
|
|
((add-hook 'erc-mode-hook #'pcomplete-erc-setup)
|
|
(add-hook 'erc-complete-functions #'erc-pcompletions-at-point)
|
|
(erc-buffer-list #'pcomplete-erc-setup))
|
|
((remove-hook 'erc-mode-hook #'pcomplete-erc-setup)
|
|
(remove-hook 'erc-complete-functions #'erc-pcompletions-at-point)))
|
|
|
|
(defun erc-pcompletions-at-point ()
|
|
"ERC completion data from pcomplete.
|
|
for use on `completion-at-point-function'."
|
|
(when (> (point) (erc-beg-of-input-line))
|
|
(or (let ((pcomplete-default-completion-function #'ignore))
|
|
(pcomplete-completions-at-point))
|
|
(let ((c (pcomplete-completions-at-point)))
|
|
(if c (nconc c '(:exclusive no)))))))
|
|
|
|
(defun erc-pcomplete ()
|
|
"Complete the nick before point."
|
|
(declare (obsolete completion-at-point "25.1"))
|
|
(interactive)
|
|
(when (> (point) (erc-beg-of-input-line))
|
|
(let ((completion-at-point-functions '(erc-pcompletions-at-point)))
|
|
(completion-at-point))))
|
|
|
|
;;; Setup function
|
|
|
|
(defun pcomplete-erc-setup ()
|
|
"Setup `erc-mode' to use pcomplete."
|
|
(setq-local completion-ignore-case t)
|
|
(setq-local pcomplete-use-paring nil)
|
|
(setq-local pcomplete-parse-arguments-function
|
|
#'pcomplete-erc-parse-arguments)
|
|
(setq-local pcomplete-command-completion-function
|
|
#'pcomplete/erc-mode/complete-command)
|
|
(setq-local pcomplete-command-name-function
|
|
#'pcomplete-erc-command-name)
|
|
(setq-local pcomplete-default-completion-function
|
|
(lambda () (pcomplete-here (pcomplete-erc-nicks)))))
|
|
|
|
;;; Programmable completion logic
|
|
|
|
(defun pcomplete/erc-mode/complete-command ()
|
|
(pcomplete-here
|
|
(append
|
|
(pcomplete-erc-commands)
|
|
(pcomplete-erc-nicks erc-pcomplete-nick-postfix t))))
|
|
|
|
(defvar erc-pcomplete-ctcp-commands
|
|
'("ACTION" "CLIENTINFO" "ECHO" "FINGER" "PING" "TIME" "USERINFO" "VERSION"))
|
|
|
|
(defun pcomplete/erc-mode/CTCP ()
|
|
(pcomplete-here (pcomplete-erc-nicks))
|
|
(pcomplete-here erc-pcomplete-ctcp-commands))
|
|
|
|
(defun pcomplete/erc-mode/CLEARTOPIC ()
|
|
(pcomplete-here (pcomplete-erc-channels)))
|
|
|
|
(defun pcomplete/erc-mode/DEOP ()
|
|
(while (pcomplete-here (pcomplete-erc-ops))))
|
|
|
|
(defun pcomplete/erc-mode/DESCRIBE ()
|
|
(pcomplete-here (pcomplete-erc-nicks)))
|
|
|
|
(defun pcomplete/erc-mode/IDLE ()
|
|
(while (pcomplete-here (pcomplete-erc-nicks))))
|
|
|
|
(defun pcomplete/erc-mode/KICK ()
|
|
(pcomplete-here (pcomplete-erc-channels))
|
|
(pcomplete-here (pcomplete-erc-nicks)))
|
|
|
|
(defun pcomplete/erc-mode/LOAD ()
|
|
(pcomplete-here (pcomplete-entries)))
|
|
|
|
(defun pcomplete/erc-mode/MODE ()
|
|
(pcomplete-here (pcomplete-erc-channels))
|
|
(while (pcomplete-here (pcomplete-erc-nicks))))
|
|
|
|
(defun pcomplete/erc-mode/ME ()
|
|
(while (pcomplete-here (pcomplete-erc-nicks))))
|
|
|
|
(defun pcomplete/erc-mode/SAY ()
|
|
(pcomplete-here (pcomplete-erc-nicks))
|
|
(pcomplete-here (pcomplete-erc-nicks))
|
|
(while (pcomplete-here (pcomplete-erc-nicks))))
|
|
|
|
(defun pcomplete/erc-mode/MSG ()
|
|
(pcomplete-here (append (pcomplete-erc-all-nicks)
|
|
(pcomplete-erc-channels)))
|
|
(while (pcomplete-here (pcomplete-erc-nicks))))
|
|
|
|
(defun pcomplete/erc-mode/NAMES ()
|
|
(while (pcomplete-here (pcomplete-erc-channels))))
|
|
|
|
(defalias 'pcomplete/erc-mode/NOTICE #'pcomplete/erc-mode/MSG)
|
|
|
|
(defun pcomplete/erc-mode/OP ()
|
|
(while (pcomplete-here (pcomplete-erc-not-ops))))
|
|
|
|
(defun pcomplete/erc-mode/PART ()
|
|
(pcomplete-here (pcomplete-erc-channels)))
|
|
|
|
(defalias 'pcomplete/erc-mode/LEAVE #'pcomplete/erc-mode/PART)
|
|
|
|
(defun pcomplete/erc-mode/QUERY ()
|
|
(pcomplete-here (append (pcomplete-erc-all-nicks)
|
|
(pcomplete-erc-channels)))
|
|
(while (pcomplete-here (pcomplete-erc-nicks)))
|
|
)
|
|
|
|
(defun pcomplete/erc-mode/SOUND ()
|
|
(while (pcomplete-here (pcomplete-entries))))
|
|
|
|
(defun pcomplete/erc-mode/TOPIC ()
|
|
(pcomplete-here (pcomplete-erc-channels)))
|
|
|
|
(defun pcomplete/erc-mode/WHOIS ()
|
|
(while (pcomplete-here (pcomplete-erc-nicks))))
|
|
|
|
(defun pcomplete/erc-mode/UNIGNORE ()
|
|
(pcomplete-here (erc-with-server-buffer erc-ignore-list)))
|
|
|
|
(defun pcomplete/erc-mode/RECONNECT ()
|
|
(pcomplete-here '("cancel"))
|
|
(pcomplete-opt "a"))
|
|
|
|
(defun pcomplete/erc-mode/BANLIST ()
|
|
(pcomplete-opt "f"))
|
|
(defalias 'pcomplete/erc-mode/BL #'pcomplete/erc-mode/BANLIST)
|
|
|
|
(defun pcomplete/erc-mode/MASSUNBAN ()
|
|
(pcomplete-opt "f"))
|
|
(defalias 'pcomplete/erc-mode/MUB #'pcomplete/erc-mode/MASSUNBAN)
|
|
|
|
;;; Functions that provide possible completions.
|
|
|
|
(defun pcomplete-erc-commands ()
|
|
"Return a list of strings of the defined user commands."
|
|
(let ((case-fold-search nil))
|
|
(mapcar (lambda (x)
|
|
(concat "/" (downcase (substring (symbol-name x) 8))))
|
|
(apropos-internal "erc-cmd-[A-Z]+"))))
|
|
|
|
(defun pcomplete-erc-ops ()
|
|
"Return a list of nicks with ops."
|
|
(let (ops)
|
|
(maphash (lambda (nick cdata)
|
|
(if (and (cdr cdata)
|
|
(erc-channel-user-op (cdr cdata)))
|
|
(setq ops (cons nick ops))))
|
|
erc-channel-users)
|
|
ops))
|
|
|
|
(defun pcomplete-erc-not-ops ()
|
|
"Return a list of nicks without ops."
|
|
(let (not-ops)
|
|
(maphash (lambda (nick cdata)
|
|
(if (and (cdr cdata)
|
|
(not (erc-channel-user-op (cdr cdata))))
|
|
(setq not-ops (cons nick not-ops))))
|
|
erc-channel-users)
|
|
not-ops))
|
|
|
|
|
|
(defun pcomplete-erc-nicks (&optional postfix ignore-self)
|
|
"Return a list of nicks in the current channel.
|
|
Optional argument POSTFIX is something to append to the nickname.
|
|
If optional argument IGNORE-SELF is non-nil, don't return the current nick."
|
|
(let ((users (if erc-pcomplete-order-nickname-completions
|
|
(erc-sort-channel-users-by-activity
|
|
(erc-get-channel-user-list))
|
|
(erc-get-channel-user-list)))
|
|
(nicks nil))
|
|
(dolist (user users)
|
|
(unless (or (not user)
|
|
(and ignore-self
|
|
(string= (erc-server-user-nickname (car user))
|
|
(erc-current-nick))))
|
|
(setq nicks (cons (concat (erc-server-user-nickname (car user))
|
|
postfix)
|
|
nicks))))
|
|
(nreverse nicks)))
|
|
|
|
(defun pcomplete-erc-all-nicks (&optional postfix)
|
|
"Return a list of all nicks on the current server."
|
|
(let (nicks)
|
|
(erc-with-server-buffer
|
|
(maphash (lambda (_nick user)
|
|
(setq nicks (cons
|
|
(concat (erc-server-user-nickname user) postfix)
|
|
nicks)))
|
|
erc-server-users))
|
|
nicks))
|
|
|
|
(defun pcomplete-erc-channels ()
|
|
"Return a list of channels associated with the current server."
|
|
(mapcar (lambda (buf) (with-current-buffer buf (erc-default-target)))
|
|
(erc-channel-list erc-server-process)))
|
|
|
|
;;; Functions for parsing
|
|
|
|
(defun pcomplete-erc-command-name ()
|
|
"Return the command name of the first argument."
|
|
(if (eq (elt (pcomplete-arg 'first) 0) ?/)
|
|
(upcase (substring (pcomplete-arg 'first) 1))
|
|
"SAY"))
|
|
|
|
(defun pcomplete-erc-parse-arguments ()
|
|
"Return a list of parsed whitespace-separated arguments.
|
|
These are the words from the beginning of the line after the prompt
|
|
up to where point is right now."
|
|
(let* ((start erc-input-marker)
|
|
(end (point))
|
|
args beginnings)
|
|
(save-excursion
|
|
(if (< (skip-chars-backward " \t\n" start) 0)
|
|
(setq args '("")
|
|
beginnings (list end)))
|
|
(setq end (point))
|
|
(while (< (skip-chars-backward "^ \t\n" start) 0)
|
|
(setq beginnings (cons (point) beginnings)
|
|
args (cons (buffer-substring-no-properties
|
|
(point) end)
|
|
args))
|
|
(skip-chars-backward " \t\n" start)
|
|
(setq end (point))))
|
|
(cons args beginnings)))
|
|
|
|
(provide 'erc-pcomplete)
|
|
|
|
;;; erc-pcomplete.el ends here
|
|
;;
|
|
;; Local Variables:
|
|
;; generated-autoload-file: "erc-loaddefs.el"
|
|
;; End:
|